新手牧师，内容不包含戒律
第一天赋：暗影
第二天赋：神圣
※ 预设饰品
神：蜘蛛之拥(13)、远虑咒符(14)
暗：蜘蛛之拥(13)、战犯印记(14)

---
#showtooltip
/cast [spec:1] 吸血鬼的拥抱
/stopmacro [spec:1]
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 守护圣灵
◎ 暗：吸血鬼的拥抱
     神：守护圣灵
◎ 守护圣灵的优先权：滑鼠指向 > 友善目标 > 目标的目标 > 自己
◎ 笔者预设按键：~

#showtooltip
/stopcasting
/cast 心灵尖啸
◎ 即时性的恐惧
◎ 笔者预设按键：alt+1

#showtooltip
/stopcasting
/cast 渐隐术
◎ 即时性的渐隐
◎ 笔者预设按键：alt+2

#showtooltip 暗影恶魔
/cast [spec:1,stance:0] 暗影形态; [spec:1,stance:1,nopet,harm][spec:2,nopet,harm] 暗影恶魔; [pet] 遁影
/stopmacro [spec:2]
/changeactionbar 1
◎ 暗：
     一般形态 按下即进入暗影形态 ( 同时切换到第一快捷键 )
     暗影形态 按下则施放暗影恶魔 ( 条件：有敌对目标 )
     神：
     施放暗影恶魔 ( 条件：有敌对目标 )
◎ 任何天赋形态下只要恶魔存在，则使用宠物技：遁影
◎ 笔者预设按键：shift+1

#showtooltip
/cast [modifier:alt] 神圣新星
/stopmacro [modifier:alt]
/cast [spec:1,stance:1,target=player][target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 真言术:盾
◎ 一般使用盾
     暗影型态下强制对自己放盾
◎ 盾的优先权：滑鼠指向 > 友善目标 > 目标的目标 > 自己
◎ 同时按下 alt 强制使用神圣新星
◎ 笔者预设按键：Q

#showtooltip
/cast [modifier:alt] 心灵烙印
/stopmacro [modifier:alt]
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 癒合祷言
◎ 一般使用癒合祷言
◎ 癒合祷言的优先权：滑鼠指向 > 友善目标 > 目标的目标 > 自己
◎ 同时按下 alt 强制使用心灵烙印
◎ 笔者预设按键：E

#showtooltip
/stopcasting
/cast [modifier:alt] !射击; [spec:1] 暗言术:死
/stopmacro [spec:1]
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 治疗之环
◎ 暗：暗言术:死
     神：治疗之环
◎ 治疗之环的优先权：滑鼠指向 > 友善目标 > 目标的目标 > 自己
◎ 任何天赋同时按下 alt 强制甩魔杖
◎ 笔者预设按键：滑鼠按键5

#showtooltip
/stopcasting
/focus [modifier:alt][target=focus,dead][target=focus,noexists]
/cast [target=focus] 束缚不死生物
◎ 简易的控场巨集
◎ 将目标设定为监控状态、并施放束缚不死生物 ( 同时按下 alt 可改变目标 )
◎ 笔者预设按键：V

#showtooltip [spec:1] 精神鞭笞; [spec:2] 惩击
/stopmacro [noharm]
/use [spec:1] 14
/cast [spec:1] !精神鞭笞; [spec:2] 惩击
/script UIErrorsFrame:Clear()
◎ 暗：精神鞭笞
     神：惩击
◎ 非常简单的巨集
     目的只是为了避免鞭笞的重置
     多加入主动式饰品施放 & 禁止画面中央错误讯息

#showtooltip
/cast [button:1] 漂浮术
/stopmacro [button:1]
/cancelaura 漂浮术
◎ 简易的漂浮术
     左键施放，任意键解除

#showtooltip
/cast [button:2,group] 坚韧祷言; 真言术:韧

#showtooltip
/cast [button:2,group] 精神祷言; 神圣精神

#showtooltip
/cast [button:2,group] 暗影防护祷言; 暗影防护
◎ 简易的巨集
◎ 队伍状态下点击右键才可施放全体技能

#showtooltip
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 恢复

#showtooltip
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 快速治疗

#showtooltip
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 强效治疗术

#showtooltip
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 束缚治疗

#showtooltip
/cast [target=mouseover,nomod,exists][help][target=targettarget,help][target=player] 治疗祷言
◎ 简易的治疗巨集
◎ 优先权：滑鼠指向 > 友善目标 > 目标的目标 > 自己

#showtooltip
/stopmacro [combat]
/cast 复活术
/stopmacro [nohelp]
/y 正在对「%t」施放复活术！
/script SendChatMessage("对你施放「复活术」！","Whisper","通用语",UnitName("target"));
◎ 通报类型的巨集 (同时密语及喊话提示)
◎ 无目标时则不喊话 ( 当目标释放灵魂后，才不会出现「未知目标」)

/equipset [spec:2] 暗牧; [spec:1] 神牧
/usetalents [spec:2] 1; [spec:1] 2
◎ 双天赋、双套装单键切换
◎ 请自行修改装备管理员名称，及对应天赋顺序

---
地狱吼 - 七彩霓虹
请依实际情况修改 ( 最后编修日期：98-06-23 )